CoolBasic SDK

MtrPerSec

Include "cbMotion.cb"

KUVAUS
Palautetaan siirtymä (metriä sekunnissa)

KÄYTTÖ
MtrPerSec(mtr#)
mtr - Metrimäärä joka muutetaan pikseleiksi

Katso myös: Pelinopeus vakioksi

ESIMERKKI
SCREEN 800, 200

Include "SDK/include/cbMotion.cb"

objCar = LoadObject("media/car.bmp")

// 30 pikseliä on yksi metri
SetWorldMetrics(30)

// Kiihtyvyys (metriä sekunnissa)
Const _ACCELERATION_#   = 2.0
// Hidastuvuus (metriä sekunnissa)
Const _SLOW_DOWN_#      = 1.0
// Hidastuvuus jarrutuksessa (metriä sekunnissa)
Const _BRAKE_#          = 4.0
// Auton huippunopeus km/h
Const _MAX_SPEED_#      = 200.0

// Auton nopeus km/h
carSpeed# = 0

Repeat
    UpdateFrameTimer()
    If UpKey() Then
        carSpeed = Min(_MAX_SPEED_, carSpeed + MtrPerSec(_ACCELERATION_))
    Else
        If DownKey() Then
            carSpeed = Max(0, carSpeed - MtrPerSec(_BRAKE_))
        Else
            carSpeed = Max(0, carSpeed - MtrPerSec(_SLOW_DOWN_))
        EndIf
    EndIf
    MoveObject objCar, KmPerHour(carSpeed)
    If ObjectX(objCar) > ScreenWidth() / 2 Then PositionObject objCar, -ScreenWidth() / 2, 0
    DrawGame
    Text 0, 0,   "FPS...: " + FPS()
    Text 0, 20,  "Nopeus: " + Int(carSpeed) + " km/h"
    Text 150, 0, "Nuoli ylös=Kiihdytys   Nuoli alas=Jarrutus"
    DrawScreen
Forever